Buscador de centros públicos integrado con Facebook
Consulta SPARQL que obtiene los datos
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX loc: <http://purl.org/ctic/infraestructuras/localizacion#>
PREFIX org: <http://purl.org/ctic/infraestructuras/organizacion#>
PREFIX geonames: <http://www.geonames.org/ontology#>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX oegov: <http://www.oegov.org/core/owl/gov#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT ?organoNombre ?centro ?centroNombre ?centroTel ?edificioNombre ?bus ?image ?lat ?long ?calle ?cp ?organoPadre ?areaNombre ?homepage ?email WHERE {
?organo a org:OrganoPublico;
dct:title ?organoNombre;
org:areaOrganizativa [
skos:prefLabel ?areaNombre
] ;
org:centroServicios ?centro .
?centro dct:title ?centroNombre;
vcard:tel ?centroTel;
dct:subject [
skos:prefLabel ?centroTema;
];
org:edificio ?edificio .
?edificio dct:title ?edificioNombre;
foaf:depiction ?image;
org:direccion [
geo:lat ?lat;
geo:long ?long;
vcard:street-address ?calle;
vcard:postal-code ?cp
] .
OPTIONAL { ?edificio org:bus ?bus }
OPTIONAL { ?organo org:dependeDe ?organoPadre }
OPTIONAL { ?centro foaf:homepage ?homepage }
OPTIONAL { ?centro vcard:email ?email }
}